// SPDX-License-Identifier: Apache-2.0
pragma solidity >=0.8.0;

// ====================================================================
//             _        ______     ___   _______          _
//            / \     .' ___  |  .'   `.|_   __ \        / \
//           / _ \   / .'   \_| /  .-.  \ | |__) |      / _ \
//          / ___ \  | |   ____ | |   | | |  __ /      / ___ \
//        _/ /   \ \_\ `.___]  |\  `-'  /_| |  \ \_  _/ /   \ \_
//       |____| |____|`._____.'  `.___.'|____| |___||____| |____|
// ====================================================================
// ======================== AgoraProxyAdmin ===========================
// ====================================================================

import { AgoraAccessControl } from "../access-control/AgoraAccessControl.sol";
import { ITransparentUpgradeableProxy } from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
/// @title AgoraProxyAdmin
/// @notice A proxy admin contract that allows for multiple admins to be set for better business continuity
/// @author Agora

contract AgoraProxyAdmin is AgoraAccessControl {
    /// @notice Initializes the contract with the initial owner
    /// @param _initialAccessControlAdminAddress The address that will be set as the initial admin of the contract
    constructor(address _initialAccessControlAdminAddress) {
        _initializeAgoraAccessControl({ _initialAdminAddress: _initialAccessControlAdminAddress });
    }

    /// @notice Upgrades the proxy to a new implementation and calls the target with the provided calldata
    /// @param _proxy The proxy to upgrade
    /// @param _implementation The new implementation address
    /// @param _calldata The data to call on the new implementation
    function upgradeAndCall(
        ITransparentUpgradeableProxy _proxy,
        address _implementation,
        bytes memory _calldata
    ) public payable virtual {
        _requireSenderIsRole({ _role: ACCESS_CONTROL_MANAGER_ROLE });
        _proxy.upgradeToAndCall{ value: msg.value }(_implementation, _calldata);
    }

    struct Version {
        uint256 major;
        uint256 minor;
        uint256 patch;
    }

    function version() public pure returns (Version memory _version) {
        return Version({ major: 1, minor: 0, patch: 0 });
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity >=0.8.0;

// ====================================================================
//             _        ______     ___   _______          _
//            / \     .' ___  |  .'   `.|_   __ \        / \
//           / _ \   / .'   \_| /  .-.  \ | |__) |      / _ \
//          / ___ \  | |   ____ | |   | | |  __ /      / ___ \
//        _/ /   \ \_\ `.___]  |\  `-'  /_| |  \ \_  _/ /   \ \_
//       |____| |____|`._____.'  `.___.'|____| |___||____| |____|
// ====================================================================
// ======================== AgoraAccessControl ========================
// ====================================================================

import { EnumerableSet } from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";

/// @title AgoraAccessControl
/// @notice An abstract contract which contains role-ba
abstract contract AgoraAccessControl {
    using EnumerableSet for EnumerableSet.AddressSet;
    using EnumerableSet for EnumerableSet.Bytes32Set;

    string public constant ACCESS_CONTROL_MANAGER_ROLE = "ACCESS_CONTROL_MANAGER_ROLE";

    /// @notice The AgoraAccessControlStorage struct
    /// @param roleData A mapping of role identifier to AgoraAccessControlRoleData to store role data
    /// @custom:storage-location erc7201:AgoraAccessControl.AgoraAccessControlStorage
    struct AgoraAccessControlStorage {
        EnumerableSet.Bytes32Set roles;
        mapping(string _role => EnumerableSet.AddressSet membership) roleMembership;
    }

    //==============================================================================
    // Initialization Functions
    //==============================================================================

    function _initializeAgoraAccessControl(address _initialAdminAddress) internal {
        _addRoleToSet({ _role: ACCESS_CONTROL_MANAGER_ROLE });
        _setRoleMembership({ _role: ACCESS_CONTROL_MANAGER_ROLE, _address: _initialAdminAddress, _insert: true });
        emit RoleAssigned({ role: ACCESS_CONTROL_MANAGER_ROLE, address_: _initialAdminAddress });
    }

    // ============================================================================================
    // Procedural Functions
    // ============================================================================================

    /// @notice The ```assignRole``` function assigns the designated role to an address
    /// @dev Must be called by the Admin
    /// @param _newAddress The address to be assigned the role
    function assignRole(string memory _role, address _newAddress, bool _addRole) public virtual {
        // Checks: Only Admin can transfer role
        _requireIsRole({ _role: ACCESS_CONTROL_MANAGER_ROLE, _address: msg.sender });

        _assignRole({ _role: _role, _newAddress: _newAddress, _addRole: _addRole });
        if (
            bytes(_role).length == bytes(ACCESS_CONTROL_MANAGER_ROLE).length &&
            keccak256(bytes(_role)) == keccak256(bytes(ACCESS_CONTROL_MANAGER_ROLE)) &&
            _getPointerToAgoraAccessControlStorage().roleMembership[_role].length() == 0
        ) revert CannotRemoveLastManager();
    }

    function _assignRole(string memory _role, address _newAddress, bool _addRole) internal {
        // Effects: Add role to set, no-op if role already exists
        _addRoleToSet({ _role: _role });

        // Effects: Set the roleMembership to the new address
        _setRoleMembership({ _role: _role, _address: _newAddress, _insert: _addRole });

        // Emit event
        if (_addRole) emit RoleAssigned({ role: _role, address_: _newAddress });
        else emit RoleRevoked({ role: _role, address_: _newAddress });
    }

    // ============================================================================================
    // Internal Effects Functions
    // ============================================================================================

    function _addRoleToSet(string memory _role) internal {
        // Checks: Role name must be shorter than 32 bytes
        if (bytes(_role).length > 32) revert RoleNameTooLong();
        _getPointerToAgoraAccessControlStorage().roles.add(bytes32(bytes(_role)));
    }

    function _removeRoleFromSet(string memory _role) internal {
        _getPointerToAgoraAccessControlStorage().roles.remove(bytes32(bytes(_role)));
    }

    /// @notice The ```_setRole``` function sets the role address
    /// @dev This function is to be implemented by a public function
    /// @param _role The role identifier to transfer
    /// @param _address The address of the new role
    /// @param _insert Whether to add or remove the address from the role
    function _setRoleMembership(string memory _role, address _address, bool _insert) internal {
        if (_insert) _getPointerToAgoraAccessControlStorage().roleMembership[_role].add(_address);
        else _getPointerToAgoraAccessControlStorage().roleMembership[_role].remove(_address);
    }

    // ============================================================================================
    // Internal Checks Functions
    // ============================================================================================

    /// @notice The ```_isRole``` function checks if _address is current role address
    /// @param _role The role identifier to check
    /// @param _address The address to check against the role
    /// @return Whether or not msg.sender is current role address
    function _isRole(string memory _role, address _address) internal view returns (bool) {
        return _getPointerToAgoraAccessControlStorage().roleMembership[_role].contains(_address);
    }

    /// @notice The ```_requireIsRole``` function reverts if _address is not current role address
    /// @param _role The role identifier to check
    /// @param _address The address to check against the role
    function _requireIsRole(string memory _role, address _address) internal view {
        if (!_isRole({ _role: _role, _address: _address })) revert AddressIsNotRole({ role: _role });
    }

    /// @notice The ```_requireSenderIsRole``` function reverts if msg.sender is not current role address
    /// @dev This function is to be implemented by a public function
    /// @param _role The role identifier to check
    function _requireSenderIsRole(string memory _role) internal view {
        _requireIsRole({ _role: _role, _address: msg.sender });
    }

    //==============================================================================
    // External View Functions
    //==============================================================================

    /// @notice The ```hasRole``` function checks if _address has the role
    /// @param _role The role identifier to check
    /// @param _address The address to check against the role
    /// @return Whether or not _address has the role
    function hasRole(string memory _role, address _address) external view returns (bool) {
        return _isRole({ _role: _role, _address: _address });
    }

    /// @notice The ```getRoleMembers``` function returns the members of the role
    /// @param _role The role identifier to check
    /// @return _members The members of the role
    function getRoleMembers(string memory _role) external view returns (address[] memory _members) {
        EnumerableSet.AddressSet storage _roleMembership = _getPointerToAgoraAccessControlStorage().roleMembership[
            _role
        ];
        _members = _roleMembership.values();
    }

    /// @notice The ```getAllRoles``` function returns all roles
    /// @return _roles The roles
    function getAllRoles() external view returns (string[] memory _roles) {
        uint256 _length = _getPointerToAgoraAccessControlStorage().roles.length();
        _roles = new string[](_length);
        for (uint256 i = 0; i < _length; i++) {
            _roles[i] = string(abi.encodePacked(_getPointerToAgoraAccessControlStorage().roles.at(i)));
        }
    }

    //==============================================================================
    // Erc 7201: UnstructuredNamespace Storage Functions
    //==============================================================================

    /// @notice The ```AGORA_ACCESS_CONTROL_STORAGE_SLOT``` is the storage slot for the AgoraAccessControlStorage struct
    /// @dev keccak256(abi.encode(uint256(keccak256("AgoraAccessControlStorage")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 public constant AGORA_ACCESS_CONTROL_STORAGE_SLOT =
        0x8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b000;

    /// @notice The ```_getPointerToAgoraAccessControlStorage``` function returns a pointer to the AgoraAccessControlStorage struct
    /// @return $ A pointer to the AgoraAccessControlStorage struct
    function _getPointerToAgoraAccessControlStorage() internal pure returns (AgoraAccessControlStorage storage $) {
        /// @solidity memory-safe-assembly
        assembly {
            $.slot := AGORA_ACCESS_CONTROL_STORAGE_SLOT
        }
    }

    // ============================================================================================
    // Events
    // ============================================================================================

    /// @notice The ```RoleAssigned``` event is emitted when the role is assigned
    /// @param role The string identifier of the role that was transferred
    /// @param address_ The address of the new role
    event RoleAssigned(string indexed role, address indexed address_);

    /// @notice The ```RoleRevoked``` event is emitted when the role is revoked
    /// @param role The string identifier of the role that was transferred
    event RoleRevoked(string indexed role, address indexed address_);

    // ============================================================================================
    // Errors
    // ============================================================================================

    /// @notice Emitted when role is transferred
    /// @param role The role identifier
    error AddressIsNotRole(string role);

    /// @notice Emitted when role name is too long
    error RoleNameTooLong();

    /// @notice Emitted when the last manager is removed via the public ```assignRole``` function
    /// @dev Manager role can be revoked by using the internal ```_assignRole``` function
    error CannotRemoveLastManager();
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/transparent/TransparentUpgradeableProxy.sol)

pragma solidity ^0.8.22;

import {ERC1967Utils} from "../ERC1967/ERC1967Utils.sol";
import {ERC1967Proxy} from "../ERC1967/ERC1967Proxy.sol";
import {IERC1967} from "../../interfaces/IERC1967.sol";
import {ProxyAdmin} from "./ProxyAdmin.sol";

/**
 * @dev Interface for {TransparentUpgradeableProxy}. In order to implement transparency, {TransparentUpgradeableProxy}
 * does not implement this interface directly, and its upgradeability mechanism is implemented by an internal dispatch
 * mechanism. The compiler is unaware that these functions are implemented by {TransparentUpgradeableProxy} and will not
 * include them in the ABI so this interface must be used to interact with it.
 */
interface ITransparentUpgradeableProxy is IERC1967 {
    /// @dev See {UUPSUpgradeable-upgradeToAndCall}
    function upgradeToAndCall(address newImplementation, bytes calldata data) external payable;
}

/**
 * @dev This contract implements a proxy that is upgradeable through an associated {ProxyAdmin} instance.
 *
 * To avoid https://medium.com/nomic-labs-blog/malicious-backdoors-in-ethereum-proxies-62629adf3357[proxy selector
 * clashing], which can potentially be used in an attack, this contract uses the
 * https://blog.openzeppelin.com/the-transparent-proxy-pattern/[transparent proxy pattern]. This pattern implies two
 * things that go hand in hand:
 *
 * 1. If any account other than the admin calls the proxy, the call will be forwarded to the implementation, even if
 * that call matches the {ITransparentUpgradeableProxy-upgradeToAndCall} function exposed by the proxy itself.
 * 2. If the admin calls the proxy, it can call the `upgradeToAndCall` function but any other call won't be forwarded to
 * the implementation. If the admin tries to call a function on the implementation it will fail with an error indicating
 * the proxy admin cannot fallback to the target implementation.
 *
 * These properties mean that the admin account can only be used for upgrading the proxy, so it's best if it's a
 * dedicated account that is not used for anything else. This will avoid headaches due to sudden errors when trying to
 * call a function from the proxy implementation. For this reason, the proxy deploys an instance of {ProxyAdmin} and
 * allows upgrades only if they come through it. You should think of the `ProxyAdmin` instance as the administrative
 * interface of the proxy, including the ability to change who can trigger upgrades by transferring ownership.
 *
 * NOTE: The real interface of this proxy is that defined in `ITransparentUpgradeableProxy`. This contract does not
 * inherit from that interface, and instead `upgradeToAndCall` is implicitly implemented using a custom dispatch
 * mechanism in `_fallback`. Consequently, the compiler will not produce an ABI for this contract. This is necessary to
 * fully implement transparency without decoding reverts caused by selector clashes between the proxy and the
 * implementation.
 *
 * NOTE: This proxy does not inherit from {Context} deliberately. The {ProxyAdmin} of this contract won't send a
 * meta-transaction in any way, and any other meta-transaction setup should be made in the implementation contract.
 *
 * IMPORTANT: This contract avoids unnecessary storage reads by setting the admin only during construction as an
 * immutable variable, preventing any changes thereafter. However, the admin slot defined in ERC-1967 can still be
 * overwritten by the implementation logic pointed to by this proxy. In such cases, the contract may end up in an
 * undesirable state where the admin slot is different from the actual admin. Relying on the value of the admin slot
 * is generally fine if the implementation is trusted.
 *
 * WARNING: It is not recommended to extend this contract to add additional external functions. If you do so, the
 * compiler will not check that there are no selector conflicts, due to the note above. A selector clash between any new
 * function and the functions declared in {ITransparentUpgradeableProxy} will be resolved in favor of the new one. This
 * could render the `upgradeToAndCall` function inaccessible, preventing upgradeability and compromising transparency.
 */
contract TransparentUpgradeableProxy is ERC1967Proxy {
    // An immutable address for the admin to avoid unnecessary SLOADs before each call
    // at the expense of removing the ability to change the admin once it's set.
    // This is acceptable if the admin is always a ProxyAdmin instance or similar contract
    // with its own ability to transfer the permissions to another account.
    address private immutable _admin;

    /**
     * @dev The proxy caller is the current admin, and can't fallback to the proxy target.
     */
    error ProxyDeniedAdminAccess();

    /**
     * @dev Initializes an upgradeable proxy managed by an instance of a {ProxyAdmin} with an `initialOwner`,
     * backed by the implementation at `_logic`, and optionally initialized with `_data` as explained in
     * {ERC1967Proxy-constructor}.
     */
    constructor(address _logic, address initialOwner, bytes memory _data) payable ERC1967Proxy(_logic, _data) {
        _admin = address(new ProxyAdmin(initialOwner));
        // Set the storage value and emit an event for ERC-1967 compatibility
        ERC1967Utils.changeAdmin(_proxyAdmin());
    }

    /**
     * @dev Returns the admin of this proxy.
     */
    function _proxyAdmin() internal view virtual returns (address) {
        return _admin;
    }

    /**
     * @dev If caller is the admin process the call internally, otherwise transparently fallback to the proxy behavior.
     */
    function _fallback() internal virtual override {
        if (msg.sender == _proxyAdmin()) {
            if (msg.sig != ITransparentUpgradeableProxy.upgradeToAndCall.selector) {
                revert ProxyDeniedAdminAccess();
            } else {
                _dispatchUpgradeToAndCall();
            }
        } else {
            super._fallback();
        }
    }

    /**
     * @dev Upgrade the implementation of the proxy. See {ERC1967Utils-upgradeToAndCall}.
     *
     * Requirements:
     *
     * - If `data` is empty, `msg.value` must be zero.
     */
    function _dispatchUpgradeToAndCall() private {
        (address newImplementation, bytes memory data) = abi.decode(msg.data[4:], (address, bytes));
        ERC1967Utils.upgradeToAndCall(newImplementation, data);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/ERC1967/ERC1967Utils.sol)

pragma solidity ^0.8.22;

import {IBeacon} from "../beacon/IBeacon.sol";
import {IERC1967} from "../../interfaces/IERC1967.sol";
import {Address} from "../../utils/Address.sol";
import {StorageSlot} from "../../utils/StorageSlot.sol";

/**
 * @dev This library provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[ERC-1967] slots.
 */
library ERC1967Utils {
    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

    /**
     * @dev The `implementation` of the proxy is invalid.
     */
    error ERC1967InvalidImplementation(address implementation);

    /**
     * @dev The `admin` of the proxy is invalid.
     */
    error ERC1967InvalidAdmin(address admin);

    /**
     * @dev The `beacon` of the proxy is invalid.
     */
    error ERC1967InvalidBeacon(address beacon);

    /**
     * @dev An upgrade function sees `msg.value > 0` that may be lost.
     */
    error ERC1967NonPayable();

    /**
     * @dev Returns the current implementation address.
     */
    function getImplementation() internal view returns (address) {
        return StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value;
    }

    /**
     * @dev Stores a new address in the ERC-1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        if (newImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(newImplementation);
        }
        StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value = newImplementation;
    }

    /**
     * @dev Performs implementation upgrade with additional setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-Upgraded} event.
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) internal {
        _setImplementation(newImplementation);
        emit IERC1967.Upgraded(newImplementation);

        if (data.length > 0) {
            Address.functionDelegateCall(newImplementation, data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;

    /**
     * @dev Returns the current admin.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by ERC-1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103`
     */
    function getAdmin() internal view returns (address) {
        return StorageSlot.getAddressSlot(ADMIN_SLOT).value;
    }

    /**
     * @dev Stores a new address in the ERC-1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        if (newAdmin == address(0)) {
            revert ERC1967InvalidAdmin(address(0));
        }
        StorageSlot.getAddressSlot(ADMIN_SLOT).value = newAdmin;
    }

    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {IERC1967-AdminChanged} event.
     */
    function changeAdmin(address newAdmin) internal {
        emit IERC1967.AdminChanged(getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }

    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is the keccak-256 hash of "eip1967.proxy.beacon" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;

    /**
     * @dev Returns the current beacon.
     */
    function getBeacon() internal view returns (address) {
        return StorageSlot.getAddressSlot(BEACON_SLOT).value;
    }

    /**
     * @dev Stores a new beacon in the ERC-1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        if (newBeacon.code.length == 0) {
            revert ERC1967InvalidBeacon(newBeacon);
        }

        StorageSlot.getAddressSlot(BEACON_SLOT).value = newBeacon;

        address beaconImplementation = IBeacon(newBeacon).implementation();
        if (beaconImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(beaconImplementation);
        }
    }

    /**
     * @dev Change the beacon and trigger a setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-BeaconUpgraded} event.
     *
     * CAUTION: Invoking this function has no effect on an instance of {BeaconProxy} since v5, since
     * it uses an immutable beacon without looking at the value of the ERC-1967 beacon slot for
     * efficiency.
     */
    function upgradeBeaconToAndCall(address newBeacon, bytes memory data) internal {
        _setBeacon(newBeacon);
        emit IERC1967.BeaconUpgraded(newBeacon);

        if (data.length > 0) {
            Address.functionDelegateCall(IBeacon(newBeacon).implementation(), data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Reverts if `msg.value` is not zero. It can be used to avoid `msg.value` stuck in the contract
     * if an upgrade doesn't perform an initialization call.
     */
    function _checkNonPayable() private {
        if (msg.value > 0) {
            revert ERC1967NonPayable();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/ERC1967/ERC1967Proxy.sol)

pragma solidity ^0.8.22;

import {Proxy} from "../Proxy.sol";
import {ERC1967Utils} from "./ERC1967Utils.sol";

/**
 * @dev This contract implements an upgradeable proxy. It is upgradeable because calls are delegated to an
 * implementation address that can be changed. This address is stored in storage in the location specified by
 * https://eips.ethereum.org/EIPS/eip-1967[ERC-1967], so that it doesn't conflict with the storage layout of the
 * implementation behind the proxy.
 */
contract ERC1967Proxy is Proxy {
    /**
     * @dev Initializes the upgradeable proxy with an initial implementation specified by `implementation`.
     *
     * If `_data` is nonempty, it's used as data in a delegate call to `implementation`. This will typically be an
     * encoded function call, and allows initializing the storage of the proxy like a Solidity constructor.
     *
     * Requirements:
     *
     * - If `data` is empty, `msg.value` must be zero.
     */
    constructor(address implementation, bytes memory _data) payable {
        ERC1967Utils.upgradeToAndCall(implementation, _data);
    }

    /**
     * @dev Returns the current implementation address.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by ERC-1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc`
     */
    function _implementation() internal view virtual override returns (address) {
        return ERC1967Utils.getImplementation();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC1967.sol)

pragma solidity ^0.8.20;

/**
 * @dev ERC-1967: Proxy Storage Slots. This interface contains the events defined in the ERC.
 */
interface IERC1967 {
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);

    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);

    /**
     * @dev Emitted when the beacon is changed.
     */
    event BeaconUpgraded(address indexed beacon);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/transparent/ProxyAdmin.sol)

pragma solidity ^0.8.22;

import {ITransparentUpgradeableProxy} from "./TransparentUpgradeableProxy.sol";
import {Ownable} from "../../access/Ownable.sol";

/**
 * @dev This is an auxiliary contract meant to be assigned as the admin of a {TransparentUpgradeableProxy}. For an
 * explanation of why you would want to use this see the documentation for {TransparentUpgradeableProxy}.
 */
contract ProxyAdmin is Ownable {
    /**
     * @dev The version of the upgrade interface of the contract. If this getter is missing, both `upgrade(address,address)`
     * and `upgradeAndCall(address,address,bytes)` are present, and `upgrade` must be used if no function should be called,
     * while `upgradeAndCall` will invoke the `receive` function if the third argument is the empty byte string.
     * If the getter returns `"5.0.0"`, only `upgradeAndCall(address,address,bytes)` is present, and the third argument must
     * be the empty byte string if no function should be called, making it impossible to invoke the `receive` function
     * during an upgrade.
     */
    string public constant UPGRADE_INTERFACE_VERSION = "5.0.0";

    /**
     * @dev Sets the initial owner who can perform upgrades.
     */
    constructor(address initialOwner) Ownable(initialOwner) {}

    /**
     * @dev Upgrades `proxy` to `implementation` and calls a function on the new implementation.
     * See {TransparentUpgradeableProxy-_dispatchUpgradeToAndCall}.
     *
     * Requirements:
     *
     * - This contract must be the admin of `proxy`.
     * - If `data` is empty, `msg.value` must be zero.
     */
    function upgradeAndCall(
        ITransparentUpgradeableProxy proxy,
        address implementation,
        bytes memory data
    ) public payable virtual onlyOwner {
        proxy.upgradeToAndCall{value: msg.value}(implementation, data);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/beacon/IBeacon.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is the interface that {BeaconProxy} expects of its beacon.
 */
interface IBeacon {
    /**
     * @dev Must return an address that can be used as a delegate call target.
     *
     * {UpgradeableBeacon} will check that this address is a contract.
     */
    function implementation() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, bytes memory returndata) = recipient.call{value: amount}("");
        if (!success) {
            _revert(returndata);
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC-1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     // Define the slot. Alternatively, use the SlotDerivation library to derive the slot.
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(newImplementation.code.length > 0);
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * TIP: Consider using this library along with {SlotDerivation}.
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct Int256Slot {
        int256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Int256Slot` with member `value` located at `slot`.
     */
    function getInt256Slot(bytes32 slot) internal pure returns (Int256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns a `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/Proxy.sol)

pragma solidity ^0.8.20;

/**
 * @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
 * instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
 * be specified by overriding the virtual {_implementation} function.
 *
 * Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
 * different contract through the {_delegate} function.
 *
 * The success and return data of the delegated call will be returned back to the caller of the proxy.
 */
abstract contract Proxy {
    /**
     * @dev Delegates the current call to `implementation`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _delegate(address implementation) internal virtual {
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())

            // Call the implementation.
            // out and outsize are 0 because we don't know the size yet.
            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)

            // Copy the returned data.
            returndatacopy(0, 0, returndatasize())

            switch result
            // delegatecall returns 0 on error.
            case 0 {
                revert(0, returndatasize())
            }
            default {
                return(0, returndatasize())
            }
        }
    }

    /**
     * @dev This is a virtual function that should be overridden so it returns the address to which the fallback
     * function and {_fallback} should delegate.
     */
    function _implementation() internal view virtual returns (address);

    /**
     * @dev Delegates the current call to the address returned by `_implementation()`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _fallback() internal virtual {
        _delegate(_implementation());
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
     * function in the contract matches the call data.
     */
    fallback() external payable virtual {
        _fallback();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

{
  "remappings": [
    "agora-std/=lib/agora-standard-solidity/src/",
    "forge-std/=lib/forge-std/src/",
    "agora-contracts/=node_modules/agora-contracts/src/contracts/",
    "stable-swap/=node_modules/@agora-finance/stable-swap/src/",
    "createx/=node_modules/createx/src/",
    "@agora-finance/=node_modules/@agora-finance/",
    "@chainlink/=lib/agora-standard-solidity/node_modules/@chainlink/",
    "@eth-optimism/=lib/agora-standard-solidity/node_modules/@eth-optimism/",
    "@openzeppelin/=node_modules/@openzeppelin/",
    "agora-standard-solidity/=lib/agora-standard-solidity/src/",
    "ds-test/=node_modules/ds-test/",
    "openzeppelin/=node_modules/createx/lib/openzeppelin-contracts/contracts/",
    "solady/=node_modules/createx/lib/solady/src/",
    "solidity-bytes-utils/=lib/agora-standard-solidity/node_modules/solidity-bytes-utils/"
  ],
  "optimizer": {
    "enabled": true,
    "runs": 100000000
  },
  "metadata": {
    "useLiteralContent": false,
    "bytecodeHash": "none",
    "appendCBOR": false
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "evmVersion": "cancun",
  "viaIR": true,
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"_initialAccessControlAdminAddress","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"inputs":[{"internalType":"string","name":"role","type":"string"}],"name":"AddressIsNotRole","type":"error"},{"inputs":[],"name":"CannotRemoveLastManager","type":"error"},{"inputs":[],"name":"RoleNameTooLong","type":"error"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"string","name":"role","type":"string"},{"indexed":true,"internalType":"address","name":"address_","type":"address"}],"name":"RoleAssigned","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"string","name":"role","type":"string"},{"indexed":true,"internalType":"address","name":"address_","type":"address"}],"name":"RoleRevoked","type":"event"},{"inputs":[],"name":"ACCESS_CONTROL_MANAGER_ROLE","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"AGORA_ACCESS_CONTROL_STORAGE_SLOT","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"string","name":"_role","type":"string"},{"internalType":"address","name":"_newAddress","type":"address"},{"internalType":"bool","name":"_addRole","type":"bool"}],"name":"assignRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"getAllRoles","outputs":[{"internalType":"string[]","name":"_roles","type":"string[]"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"string","name":"_role","type":"string"}],"name":"getRoleMembers","outputs":[{"internalType":"address[]","name":"_members","type":"address[]"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"string","name":"_role","type":"string"},{"internalType":"address","name":"_address","type":"address"}],"name":"hasRole","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"contract ITransparentUpgradeableProxy","name":"_proxy","type":"address"},{"internalType":"address","name":"_implementation","type":"address"},{"internalType":"bytes","name":"_calldata","type":"bytes"}],"name":"upgradeAndCall","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[],"name":"version","outputs":[{"components":[{"internalType":"uint256","name":"major","type":"uint256"},{"internalType":"uint256","name":"minor","type":"uint256"},{"internalType":"uint256","name":"patch","type":"uint256"}],"internalType":"struct AgoraProxyAdmin.Version","name":"_version","type":"tuple"}],"stateMutability":"pure","type":"function"}]

0x60806040523461014557604051601f6111e538819003918201601f19168301916001600160401b038311848410176101495780849260209460405283398101031261014557516001600160a01b038116908190036101455761005f61015d565b60208151116101365761008390602081519101519060208110610125575b506101cf565b506100cf8160208061009361015d565b604051928184925191829101835e81017f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b002815203019020610287565b5060206100da61015d565b604051918183925191829101835e81015f815203902090604051917f1cf4c2f10398d18e27c3336eeadbf9ce9571462b7cb30d5d9a4024580f208d215f80a3610ec490816102e18239f35b5f199060200360031b1b165f61007d565b6337d8d20960e01b5f5260045ffd5b5f80fd5b634e487b7160e01b5f52604160045260245ffd5b60408051919082016001600160401b0381118382101761014957604052601b82527f4143434553535f434f4e54524f4c5f4d414e414745525f524f4c4500000000006020830152565b80548210156101bb575f5260205f2001905f90565b634e487b7160e01b5f52603260045260245ffd5b805f525f5160206111a55f395f51905f5260205260405f2054155f14610282575f5160206111c55f395f51905f5254680100000000000000008110156101495761025361023d8260018594015f5160206111c55f395f51905f52555f5160206111c55f395f51905f526101a6565b819391549060031b91821b915f19901b19161790565b90555f5160206111c55f395f51905f5254905f525f5160206111a55f395f51905f5260205260405f2055600190565b505f90565b6001810190825f528160205260405f2054155f146102d957805468010000000000000000811015610149576102c661023d8260018794018555846101a6565b905554915f5260205260405f2055600190565b5050505f9056fe60806040526004361015610011575f80fd5b5f5f3560e01c80633a9a676e1461065e578063414c5f501461060d5780634592d7231461051957806354fd4d501461049c5780636c9cd097146104025780639623609d146102d4578063bebcab561461027b5763f2bcac3d14610072575f80fd5b3461027857807ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc360112610278577f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054906100cc82610aa6565b916100da6040519384610904565b8083527fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe061010782610aa6565b01825b8181106102655750507f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054825b8281106101c2575050506040519182916020830160208452825180915260408401602060408360051b870101940192905b82821061017757505050500390f35b919360206101b2827fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc060019597998495030186528851610a25565b9601920192018594939192610168565b9293919281811015610238576001907f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b0008652806020872001548660031b1c60405190602082015260208152610218604082610904565b6102228286610abe565b5261022d8185610abe565b500193929193610137565b6024857f4e487b710000000000000000000000000000000000000000000000000000000081526032600452fd5b606060208287018101919091520161010a565b80fd5b503461027857807ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126102785760206040517f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b0008152f35b5060607ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043573ffffffffffffffffffffffffffffffffffffffff81168091036103fe576103286109c7565b60443567ffffffffffffffff81116103fe57366023820112156103fe57610359903690602481600401359101610945565b61036b6103646109ea565b3390610aff565b823b156103fe576103d19273ffffffffffffffffffffffffffffffffffffffff5f93604051958694859384937f4f1ef286000000000000000000000000000000000000000000000000000000008552166004840152604060248401526044830190610a25565b039134905af180156103f3576103e5575080f35b6103f191505f90610904565b005b6040513d5f823e3d90fd5b5f80fd5b346103fe5760407ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe5761049261045660209236906004016109a9565b73ffffffffffffffffffffffffffffffffffffffff61047c6104766109c7565b92610a68565b9116906001915f520160205260405f2054151590565b6040519015158152f35b346103fe575f7ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe575f604080516104d8816108bb565b828152826020820152015260606040516104f1816108bb565b60018152604060208201915f8352015f81526040519160018352516020830152516040820152f35b346103fe5760207ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe5761056b6105709136906004016109a9565b610a68565b604051806020835491828152019081935f5260205f20905f5b8181106105f7575050508161059f910382610904565b604051918291602083019060208452518091526040830191905f5b8181106105c8575050500390f35b825173ffffffffffffffffffffffffffffffffffffffff168452859450602093840193909201916001016105ba565b8254845260209093019260019283019201610589565b346103fe575f7ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5761065a6106466109ea565b604051918291602083526020830190610a25565b0390f35b346103fe5760607ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe576106ad9036906004016109a9565b6106b56109c7565b906044359182151583036103fe576106ce6103646109ea565b6020825111610893578151926106f4602084019485519060208110610863575b50610b9d565b5080156108345761072461070784610a68565b73ffffffffffffffffffffffffffffffffffffffff841690610ce6565b505b156107ea5773ffffffffffffffffffffffffffffffffffffffff61074983610b6c565b9116907f1cf4c2f10398d18e27c3336eeadbf9ce9571462b7cb30d5d9a4024580f208d215f80a35b805161077b6109ea565b511491826107cc575b50816107ba575b5061079257005b7f3cba491a000000000000000000000000000000000000000000000000000000005f5260045ffd5b6107c49150610a68565b54158161078b565b908092505190206107db6109ea565b60208151910120149082610784565b73ffffffffffffffffffffffffffffffffffffffff61080883610b6c565b9116907f1e5d48c75f77ab7fd581247d777530d4e8c18432289e14017ba995532f6ca1cf5f80a3610771565b61085d61084084610a68565b73ffffffffffffffffffffffffffffffffffffffff841690610d3e565b50610726565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff9060200360031b1b16866106ee565b7f37d8d209000000000000000000000000000000000000000000000000000000005f5260045ffd5b6060810190811067ffffffffffffffff8211176108d757604052565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52604160045260245ffd5b90601f7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0910116810190811067ffffffffffffffff8211176108d757604052565b92919267ffffffffffffffff82116108d7576040519161098d601f82017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe01660200184610904565b8294818452818301116103fe578281602093845f960137010152565b9080601f830112156103fe578160206109c493359101610945565b90565b6024359073ffffffffffffffffffffffffffffffffffffffff821682036103fe57565b604051906109f9604083610904565b601b82527f4143434553535f434f4e54524f4c5f4d414e414745525f524f4c4500000000006020830152565b907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0601f602080948051918291828752018686015e5f8582860101520116010190565b60208091604051928184925191829101835e81017f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00281520301902090565b67ffffffffffffffff81116108d75760051b60200190565b8051821015610ad25760209160051b010190565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52603260045260245ffd5b90610b229073ffffffffffffffffffffffffffffffffffffffff61047c84610a68565b15610b2a5750565b610b68906040519182917fc13dd0f3000000000000000000000000000000000000000000000000000000008352602060048401526024830190610a25565b0390fd5b602090604051918183925191829101835e81015f815203902090565b8054821015610ad2575f5260205f2001905f90565b805f527f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00160205260405f2054155f14610ce1577f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054680100000000000000008110156108d757610c8c610c578260018594017f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b000557f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b000610b88565b81939154907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff9060031b92831b921b19161790565b90557f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054905f527f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00160205260405f2055600190565b505f90565b5f828152600182016020526040902054610d3857805490680100000000000000008210156108d75782610d23610c57846001809601855584610b88565b90558054925f520160205260405f2055600190565b50505f90565b906001820191815f528260205260405f20548015155f14610ebc577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8101818111610e8f578254907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8201918211610e8f57818103610e5a575b50505080548015610e2d577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0190610df08282610b88565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff82549160031b1b19169055555f526020525f6040812055600190565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52603160045260245ffd5b610e7a610e6a610c579386610b88565b90549060031b1c92839286610b88565b90555f528360205260405f20555f8080610db8565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52601160045260245ffd5b505050505f90568f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b0018f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00000000000000000000000000099b0e95fa8f5c3b86e4d78ed715b475cfccf6e97

0x60806040526004361015610011575f80fd5b5f5f3560e01c80633a9a676e1461065e578063414c5f501461060d5780634592d7231461051957806354fd4d501461049c5780636c9cd097146104025780639623609d146102d4578063bebcab561461027b5763f2bcac3d14610072575f80fd5b3461027857807ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc360112610278577f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054906100cc82610aa6565b916100da6040519384610904565b8083527fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe061010782610aa6565b01825b8181106102655750507f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054825b8281106101c2575050506040519182916020830160208452825180915260408401602060408360051b870101940192905b82821061017757505050500390f35b919360206101b2827fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc060019597998495030186528851610a25565b9601920192018594939192610168565b9293919281811015610238576001907f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b0008652806020872001548660031b1c60405190602082015260208152610218604082610904565b6102228286610abe565b5261022d8185610abe565b500193929193610137565b6024857f4e487b710000000000000000000000000000000000000000000000000000000081526032600452fd5b606060208287018101919091520161010a565b80fd5b503461027857807ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126102785760206040517f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b0008152f35b5060607ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043573ffffffffffffffffffffffffffffffffffffffff81168091036103fe576103286109c7565b60443567ffffffffffffffff81116103fe57366023820112156103fe57610359903690602481600401359101610945565b61036b6103646109ea565b3390610aff565b823b156103fe576103d19273ffffffffffffffffffffffffffffffffffffffff5f93604051958694859384937f4f1ef286000000000000000000000000000000000000000000000000000000008552166004840152604060248401526044830190610a25565b039134905af180156103f3576103e5575080f35b6103f191505f90610904565b005b6040513d5f823e3d90fd5b5f80fd5b346103fe5760407ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe5761049261045660209236906004016109a9565b73ffffffffffffffffffffffffffffffffffffffff61047c6104766109c7565b92610a68565b9116906001915f520160205260405f2054151590565b6040519015158152f35b346103fe575f7ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe575f604080516104d8816108bb565b828152826020820152015260606040516104f1816108bb565b60018152604060208201915f8352015f81526040519160018352516020830152516040820152f35b346103fe5760207ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe5761056b6105709136906004016109a9565b610a68565b604051806020835491828152019081935f5260205f20905f5b8181106105f7575050508161059f910382610904565b604051918291602083019060208452518091526040830191905f5b8181106105c8575050500390f35b825173ffffffffffffffffffffffffffffffffffffffff168452859450602093840193909201916001016105ba565b8254845260209093019260019283019201610589565b346103fe575f7ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5761065a6106466109ea565b604051918291602083526020830190610a25565b0390f35b346103fe5760607ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc3601126103fe5760043567ffffffffffffffff81116103fe576106ad9036906004016109a9565b6106b56109c7565b906044359182151583036103fe576106ce6103646109ea565b6020825111610893578151926106f4602084019485519060208110610863575b50610b9d565b5080156108345761072461070784610a68565b73ffffffffffffffffffffffffffffffffffffffff841690610ce6565b505b156107ea5773ffffffffffffffffffffffffffffffffffffffff61074983610b6c565b9116907f1cf4c2f10398d18e27c3336eeadbf9ce9571462b7cb30d5d9a4024580f208d215f80a35b805161077b6109ea565b511491826107cc575b50816107ba575b5061079257005b7f3cba491a000000000000000000000000000000000000000000000000000000005f5260045ffd5b6107c49150610a68565b54158161078b565b908092505190206107db6109ea565b60208151910120149082610784565b73ffffffffffffffffffffffffffffffffffffffff61080883610b6c565b9116907f1e5d48c75f77ab7fd581247d777530d4e8c18432289e14017ba995532f6ca1cf5f80a3610771565b61085d61084084610a68565b73ffffffffffffffffffffffffffffffffffffffff841690610d3e565b50610726565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff9060200360031b1b16866106ee565b7f37d8d209000000000000000000000000000000000000000000000000000000005f5260045ffd5b6060810190811067ffffffffffffffff8211176108d757604052565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52604160045260245ffd5b90601f7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0910116810190811067ffffffffffffffff8211176108d757604052565b92919267ffffffffffffffff82116108d7576040519161098d601f82017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe01660200184610904565b8294818452818301116103fe578281602093845f960137010152565b9080601f830112156103fe578160206109c493359101610945565b90565b6024359073ffffffffffffffffffffffffffffffffffffffff821682036103fe57565b604051906109f9604083610904565b601b82527f4143434553535f434f4e54524f4c5f4d414e414745525f524f4c4500000000006020830152565b907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0601f602080948051918291828752018686015e5f8582860101520116010190565b60208091604051928184925191829101835e81017f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00281520301902090565b67ffffffffffffffff81116108d75760051b60200190565b8051821015610ad25760209160051b010190565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52603260045260245ffd5b90610b229073ffffffffffffffffffffffffffffffffffffffff61047c84610a68565b15610b2a5750565b610b68906040519182917fc13dd0f3000000000000000000000000000000000000000000000000000000008352602060048401526024830190610a25565b0390fd5b602090604051918183925191829101835e81015f815203902090565b8054821015610ad2575f5260205f2001905f90565b805f527f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00160205260405f2054155f14610ce1577f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054680100000000000000008110156108d757610c8c610c578260018594017f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b000557f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b000610b88565b81939154907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff9060031b92831b921b19161790565b90557f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00054905f527f8f8de9240b3899c03a31968f466af060ab1c78464aa7ae14941c20fe7917b00160205260405f2055600190565b505f90565b5f828152600182016020526040902054610d3857805490680100000000000000008210156108d75782610d23610c57846001809601855584610b88565b90558054925f520160205260405f2055600190565b50505f90565b906001820191815f528260205260405f20548015155f14610ebc577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8101818111610e8f578254907fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8201918211610e8f57818103610e5a575b50505080548015610e2d577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0190610df08282610b88565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff82549160031b1b19169055555f526020525f6040812055600190565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52603160045260245ffd5b610e7a610e6a610c579386610b88565b90549060031b1c92839286610b88565b90555f528360205260405f20555f8080610db8565b7f4e487b71000000000000000000000000000000000000000000000000000000005f52601160045260245ffd5b505050505f9056